走过年华

例1：一键回血，要改为一键回蓝的话大家把物品名相对改下即可，当然亦可增添几行命令
#showtooltip  魔法肉桂面包
/use 魔法肉桂面包
/use 奥特兰克冷酪
/use [combat]厚符文布绷带
/use [combat]符文布绷带
/use [combat]优质治疗药膏
/use [combat]强效治疗药水
/use [combat]丝质绷带

例2：右键点击是在小地图上显示附近矿物图标，左键点则打开熔炼面板
#showtooltip  熔炼
/cast [button:2]寻找矿物;熔炼
例3：饰品宏，左键和右键点击分别使用装备在身上的不同饰品
#showtooltip  6级雷矛勋章
/stopcasting
/cast [button:2] 6级雷矛勋章; 赞达拉英雄护符
 

二.战士宏

例1：宏显示为冲锋的技能图标，当前目标为敌对且未处于战斗中时冲锋，否则施放挫志怒吼
# show 冲锋
/stopcasting
/cast  [harm,nocombat]冲锋
/cast 挫志怒吼

例2：这个宏就不必解释了吧，战士们一看就会明白
/stopcasting
/cast [stance:1,combat,harm]反击风暴
/cast [stance:2,combat,harm]盾墙
/cast [stance:3,combat,harm]鲁莽

例3：宏显示为斩杀的技能图标，当处于战斗姿态或狂暴姿态，目标为敌对并且在战斗中时使用斩杀；当处于防御姿态，目标为敌对并且在战斗中时使用盾击；当前面的条件都不成立时运行该宏就是召唤坐骑！
# show 斩杀
# show 盾击
/stopcasting
/cast [combat,harm,stance:1]斩杀
/cast [combat,harm,stance:3]斩杀
/cast [combat,harm,stance:2]盾击
/use 黑色军用战马缰绳

三.法师宏

例1：此宏较为复杂，具体作用大家就自己分析吧，若能熟练编写该类宏命令一定能使您操作角色更为简便！
#showtooltip 寒冰箭
/use [harm]赞达拉英雄护符
/cast [modifier:alt,harm]火球术;[harm]寒冰箭;[modifier:alt]冰甲术;[modifier:ctrl]法师护甲;[nocombat,noharm]造水术
/stopmacro [target=pettarget, exists] 
/petattack
/click [pet] PetActionButton1

例2：开启或关闭冰箱宏，若冰箱技能尚未冷却时则使用治疗药水
#showtooltip 寒冰屏障
/stopcasting
/cancelAura 寒冰屏障
/cast 寒冰屏障
/use 强效治疗药水
 例3：要是宠物存在，使用宠物快捷栏上的第8个技能（我的宝宝第8个技能为被动状态，当然大家可以自己设置）
也就是宝宝立即处于被动状态停止攻击；若当前目标为敌对时则对其施放变形术；当前面的条件均未成立，目标不是敌对且不在战斗中时施放钓鱼。
#showtooltip  变形术
/click [pet] PetActionButton8
/cast [harm]变形术;[nocombat,noharm]钓鱼

四.牧师宏

例1：当鼠标指向的目标或当前目标是友方且未死亡，使用驱散；当鼠标指向的目标或当前目标是敌对且未死亡，使用暗言术：痛；当没有目标且鼠标并未指向任何目标时对自己使用驱散！（前提是界面设置中的自我施法必须启用）
# show  暗言术：痛
/cast [target=mouseover,exists,help,nodead] 驱散魔法; [target=mouseover,exists,harm,nodead] 暗言术：痛; [help,nodead] 驱散魔法; [harm,nodead] 暗言术：痛; [target=player] 驱散魔法

例2：当目标敌对时施放暗言术：痛；当目标友善时施放真言术：盾。并且右键点击时都是对自己施放法术。
# show  真言术：盾
/cast [button:2, target=player] 真言术：盾; [help] 真言术：盾; 暗言术：痛

例3：成功复活后才通知，当暗影形态或战斗中或目标敌对或目标未死亡时，不进行动作；否则施放复活术，并通知正在复活的目标名字。这个宏可避免以前的复活宏因为复活失败却仍然喊话的尴尬。
# show  复活术
/stopmacro [stance:1/combat]
/cast 复活术
/stopmacro [nohelp/nodead]
/大喊 %t起来吧，我的勇士！
/团队 我已复活%t